DATE_ADD で前日・翌月・年度末も一発！
計算式プラグイン を使えば、日付を元にした前日・翌月・年度末などさまざまな計算が簡単にできます。
日付計算の編集画面例
「日付」項目をもとに、さまざまな形式・タイミングの日付を計算しています。
計算式の設定方法
よく使う日付関数
| 種類 | 式の例 | 説明 |
|---|---|---|
| 前日/翌日 | DATE_ADD(日付, -1, "day") / DATE_ADD(日付, 1, "day") |
日付を±1日 |
| 前月/翌月 | DATE_ADD(日付, -1, "month") / DATE_ADD(日付, 1, "month") |
月単位の加減算 |
| 前年/翌年 | DATE_ADD(日付, -1, "year") / DATE_ADD(日付, 1, "year") |
年単位の加減算 |
| 月初 | DATE_FORMAT(日付, "YYYY-MM-01") |
月の1日を取得 |
| 月末 | DATE_ENDOF(日付, "month") |
月末日を取得 |
| 翌月末 | DATE_ENDOF(DATE_ADD(日付,1,"month"),"month") |
翌月の末日 |
| 年初 | DATE_FORMAT(日付, "YYYY-01-01") |
その年の1月1日 |
| 年末 | DATE_ENDOF(日付, "year") |
年末（12/31） |
| 年度 | FISCAL_YEAR(日付, 年度始め) |
年度（開始月指定） |
| 今日 | TODAY() |
本日日付 |
日付の形式変換
DATE_FORMAT(日付, "YYYY年M月D日") // 例：2025年8月7日
DATE_FORMAT(日付, "YYYY") // 年
DATE_FORMAT(日付, "M") // 月
DATE_FORMAT(日付, "D") // 日
年度初日・年度末日
// 年度初日 DATE
LET(
fiscalStart, 年度始め, // 年度開始月日（例: "04-01"）
day, 日付, // 対象日（1回のみ使用）
year, FISCAL_YEAR(day, fiscalStart), // 年度開始年（未入力なら ""）
IF(year, year & "-" & fiscalStart) // 年度初日（空なら "" を返す）
)
// 年度末日 DATE
LET(
fiscalStart, 年度始め, // 年度開始日
day, 日付, // 日付
year, FISCAL_YEAR(day, fiscalStart), // 今日が属する年度（開始年）
nextStart, year + 1 & "-" & fiscalStart, // 翌年度の開始日（YYYY-MM-DD）
IF(year, DATE_ADD(nextStart, -1, "day")) // 年度終了日 = 翌年度開始日の前日
)
テーブル内の日付計算
テーブル内でも日付加算が可能です。たとえば、日付T に 数値T の分だけ、年月日区分を指定して加算するには：
DATE_ADD(日付T, 数値T,
SWITCH(年月日区分, "年", "year", "月", "month", "日", "day")
)
※ 2020/01/30 に「+1ヶ月」すると、2020/02/29（うるう年の月末）として自動調整されます！
参考
あとがき
計算式プラグインを使えば、日付を扱う処理が関数で思いどおりの結果が得られます！